Aula 29–Tomada de Decisão – COND

Olá pessoal hoje aprenderemos o nosso ultimo comando de tomada de decisão o COND, apesar de ser um pouco mais complicado que o IF ele é de entendimento mais fácil, mais complicado por causa da sua sintaxe, muito programadores iniciantes (isso também aconteceu comigo) preferem utilizar o COND ao IF por acharem que ele é melhor e mais fácil, porem com o passar do tempo se percebe que o COND torna o programa difícil de ser interpretado e ele pode não atender a todas as condições possíveis, as vezes (quase sempre) é melhor usar IF alinhados (aprenderemos na aula de exercícios), então tomem cuidado COND demais pode atrapalhar os seus programas, prefira sempre o IF.

A função COND executa blocos de programação se o mesmo atender as condições especificadas, podemos ter quantas condições quisermos, é possível ainda criar um bloco de informação para que o mesmo seja executado se nenhuma das condições for atendida.

Sintaxe:

(cond
((<condição 1>)
(bloco de programação da condição 1)
)
((<condição 2>)
(bloco de programação da condição 2)
)
((<condição N>)
(bloco de programação da condição N)
)
(T
(bloco de informação caso nenhuma das condições acima tenha sido atendidas)
)
)

Realmente olhando a sintaxe do COND ela realmente assusta, talvez no final dessa leitura você ainda fique assustado, porem garanto que na vídeo-aula tudo parecera mais simples.

Nada melhor que um exemplo para que consigamos entender melhor o COND.

Exemplo 1:

Vamos criar um programa que o usuário escolha entre circulo, linha ou texto e dependendo da escolha o programa rodara o fluxo de informação escolhida, nesse exemplo não vamos criar uma condição caso nenhuma das condições seja satisfatória, faremos isso no próximo exemplo.

(defun c:exc()
  (setq opcao (getstring "\nEscolha <Circle/Linha/Texto>: "))
  (cond
    ((or (= opcao "c") (= opcao "C"))
      (setq pt1 (getpoint "\nClique no local desejado: "))
      (command "circle" pt1 10)
     )
     ((or (= opcao "l") (= opcao "L"))
      (setq pt1 (getpoint "\nClique no primeiro ponto: "))
      (setq pt2 (getpoint pt1 "\nClique no segundo ponto: "))
      (command "line" pt1 pt2 "")
     )
    ((or (= opcao "t") (= opcao "T"))
      (setq pt1 (getpoint "\nClique no local desejado: "))
      (command "text" pt1 "2" "0" "Exemplo")
     )
    )
  (princ)
  )

No exemplo acima, caso o usuário digite C (em amarelo), L (em verde) ou T (em laranja) ele executara um bloco de programação especifico, porém nada acontecera caso nenhuma das condições seja atendida, no exemplo abaixo mostrarei como criar um bloco programação caso isso aconteça.

Exemplo 2:

(defun c:exc2()
  (setq opcao (getstring "\nEscolha <Circle/Linha/Texto>: "))
  (cond
    ((or (= opcao "c") (= opcao "C"))
     (setq pt1 (getpoint "\nClique no local desejado: "))
     (command "circle" pt1 10)
     )
     ((or (= opcao "l") (= opcao "L"))
      (setq pt1 (getpoint "\nClique no primeiro ponto: "))
      (setq pt2 (getpoint pt1 "\nClique no segundo ponto: "))
      (command "line" pt1 pt2 "")
      )
    ((or (= opcao "t") (= opcao "T"))
      (setq pt1 (getpoint "\nClique no local desejado: "))
      (command "text" pt1 "2" "0" "Exemplo")
      )
    (t
     (prompt "\nNenhuma das opções válidas foi selecionada.")
     )
    )
  (princ)
  )

No exemplo acima, caso o usuário digite C (em amarelo), L (em verde) ou T (em laranja) ele executara um bloco de programação especifico, porem se nenhuma dessas opções for escolhida ele fara o bloco de programação na cor vermelha, nesse caso ele emitira uma mensagem na linha de comando informando que nenhuma das opções válidas foi selecionada.

Exemplo 3:

Nesse exemplo o usuário vai digitar uma idade e vamos informar para ele se ele é uma criança, adolescente, adulto ou idoso.

(defun c:age()
  (setq idade (getint "\nDigite a sua idade: "))
  (cond
    ((and (>= idade 0)(<= idade 12))
     (alert "Voce é uma criança!!!")
     )
     ((and (> idade 12)(<= idade 17))
     (alert "Voce é um adolecente!!!")
     )
    ((and (> idade 17)(<= idade 50))
     (alert "Voce é um adulto!!!")
     )
    ((> idade 50)
     (alert "Voce é um idoso!!!")
     )
    )
  (princ)
  )

Esse é o ultimo comando de tomada de decisões, na próxima aula faremos alguns exercícios comentados para fixação do assunto.

Abaixo segue o link dessa vídeo Aula no meu canal Manual de Cad no youtube.

https://www.youtube.com/watch?v=d2KB8Em3_wM&feature=youtu.be

Espero que tenham gostado.

Sergio Fernandes

Manual de Cad 

Aula 28–Tomada de Decisão - IF

Olá pessoal hoje aprenderemos o nosso primeiro e principal função de decisão o IF que significa Se, com essa função podemos analisar determinada condição e seguir dois caminho um caso a condição seja verdadeira e  outro caso seja falsa.

Sintaxe:

(if <condições>

(<comando caso seja verdadeiro>)

(<comando caso seja falso>)

)

Note que na primeira linha abrimos um parênteses para o IF abrimos um parênteses colocamos a condição, mas não fechamos o parênteses pertencentes o IF, esse parêntese será fechado apenas no final.

Outra coisa muito importante a primeira linha é para se a condição for verdadeira e a segunda para falso, é exatamente isso uma única linha para cada, logo aprenderemos como usar mais linhas de programação dentro do if, o importante agora é entender que ele sozinho só trabalha com uma linha para falso e uma linha para verdadeiro.

Vamos ver alguns exemplo comentados:

Exemplo 1:

Vamos criar um comando onde o usuário digita o seu nome e a sua idade, caso a sua idade seja menor que 18 anos o programa emite uma mensagem de alerta informado que o usuário é menor de idade, caso seja maior de idade ele imprimira uma mensagem na linha de comando informando que o usuário é maior de idade.

(defun c:cad()
  (setq nome (getstring "\nDigite o seu primeiro nome: "))
  (setq idade (getint "nDigite a sua Idade: "))
  (if (< idade 18)
    (alert "ATENÇÃO o usuário é menor de idade.")
    (prompt "Usuário maior de idade, prossiga com seu cadastro.")
  )
  (princ)
  )

Apos o usuário digitar a sua idade e pressionar Enter o programa fara a analise da condição caso idade seja maior que 18 ele emitira uma mensagem de alerta na tela, se não ele emitira uma mensagem na linha de comando informando que esta tudo OK.

Note os parênteses em vermelho, eles mostram o inicio e o fim da função if.

Exemplo 2:

Nesse exemplo vamos aprender mais uma coisa interessante sobre o comando IF, vai acontecer varias vezes durante os seus programas a necessidade de informar o que o programa deve fazer apenas quando a condição for verdadeira e que o programa não faça nada se a condição for falsa.

No exemplo abaixo emitiremos a mensagem de alerta apenas se o usuário for menor de idade caso contrario não faremos nada, nesse caso basta suprimir a linha de comando caso a condição for falsa.

(defun c:cad2()
  (setq nome (getstring "\nDigite o seu primeiro nome: "))
  (setq idade (getint "nDigite a sua Idade: "))
  (if (< idade 18)
    (alert "ATENÇÃO o usuário é menor de idade.")
  )
  (princ)
  )

O mesmo não pode ser feito caso a condição for falsa, não podemos suprimir a linha de comando da condição verdadeira, uma forma de fazer isso é invertendo o operador logico, pois é diferente (< idade 18) e (> idade 18) isso mudara a ordem do que é falso e do que é verdadeiro.

Muito legal, porem na grande maioria das vezes uma única linha de programação não é o suficiente  para definir o que o usuário deve fazer caso seja verdadeira a condição ou caso seja falsa.

Para resolver esse problema devemos usar a seguinte sintaxe:

Sintaxe:

(if <condição>

    (progn

        <comando 1>

        <comando 2>

        <comando ……>

    )

   (progn

        <comando 1>

        <comando 2>

        <comando ……>

   )

)

Olhe bem o fechamento dos parênteses, eu os coloquei eles de cores diferentes, perceba onde começa e termina a função IF (parênteses vermelhos), depois temos a condição e depois abrimos um parênteses e escrevemos PROGN (note que o parênteses não é fechado no final do progn) abaixo do PROGN  você deve estar com toda a instrução caso a condição seja verdadeira e só depois fechar o parênteses do PROGN (parênteses amarelo e branco), caso tenhamos instruções a serem seguidas caso a condição seja falsa ai repetiremos o mesmo procedimento.

Vamos ver alguns exemplos:

Exemplo 1:

Vamos criar um programa que o usuário digite C para circulo ou qualquer coisa para linha (existe um comando melhor para fazer isso do que o getstring que não aprendemos ainda porque não valia a pena ensina-lo antes de aprender a tomada de decisão) se o usuário digitar C faremos um circulo no ponto selecionado no layer “circulo”, se ele digitar qualquer outra coisa o programa fara uma linha no layer linha.

(defun c:lc()
  (setq tipo (getstring "\Para circulo C para linha qualquer coisa: "))
  (if (or (= tipo "c") (= tipo "C"))
    (progn
      (setq pt1 (getpoint "\nClique sobre o ponto desejado: "))
      (setq raio (getreal "\nDigite o raio do circulo: "))
      (command "circle" pt1 raio)
      (command "layer" "n" "circulo" "c" "7" "circulo" "")
      (command "chprop" (entlast) "" "la" "circulo" "")
      )
    (progn
      (setq pt1 (getpoint "\nClique no primeiro ponto: "))
      (setq pt2 (getpoint pt1 "\nClique no segundo ponto: "))
      (command "line" pt1 pt2 "")
      (command "layer" "n" "linha" "c" "7" "linha" "")
      (command "chprop" (entlast) "" "la" "linha" "")
      )    )
  (princ)
  )

Agora fica mais fácil, temos dois blocos de programa que só serão executados se a condição for verdadeira ou falsa, note que a condição foi feita usando o operador logico OR ele vai executar como circulo se o usuário digitar c (minúsculo) ou C (maiúsculo), como ainda não aprendemos o tratamento de string temos que fazer assim para dar certo.

O bloco de programação em amarelo será executado for verdadeira a condição e o bloco de programação em verdade será executada se a condição for falsa.

Da mesma forma podemos ter apenas um bloco de informação para caso a condição seja verdadeira não sendo necessário escrever o bloco de programação caso seja falso.

No exemplo Abaixo temos o mesmo programa porem ele somente fara o circulo se for pressionado o C ou c, porém nada será feito se qualquer outra tecla for pressionada.

Exemplo 2:

(defun c:lc2()
  (setq tipo (getstring "\Para circulo C: "))
  (if (or (= tipo "c") (= tipo "C"))
    (progn
      (setq pt1 (getpoint "\nClique sobre o ponto desejado: "))      (setq raio (getreal "\nDigite o raio do circulo: "))      (command "circle" pt1 raio)      (command "layer" "n" "circulo" "c" "7" "circulo" "")      (command "chprop" (entlast) "" "la" "circulo" "")      )
    )
  (princ)
  )
   

Só teremos agora o bloco de programação amarelo, caso a condição seja verdadeira, caso o usuário digite qualquer coisa diferente de C ou c o programa não fara nada

Aproveitando esse exemplo vou explicar outra coisas, é possível misturar um if com progn caso seja verdadeira a condição e uma única linha caso seja falso, ou vice versa.

Exemplo 3:

(defun c:lc3()
  (setq tipo (getstring "\Para circulo C: "))
  (if (or (= tipo "c") (= tipo "C"))
   (progn      (setq pt1 (getpoint "\nClique sobre o ponto desejado: "))      (setq raio (getreal "\nDigite o raio do circulo: "))      (command "circle" pt1 raio)      (command "layer" "n" "circulo" "c" "7" "circulo" "")      (command "chprop" (entlast) "" "la" "circulo" "")      )
    (prompt "\nNenhuma opção válida foi escolhida.")
    )
  (princ)
  )

Note que temos um bloco de programação caso seja verdadeiro (em amarelo) e apenas uma linha caso seja falso, nesse caso apenas uma mensagem será impressa na linha de comando. O mesmo pode acontecer de termos uma linha caso a condição seja verdadeira e um bloco de programação caso seja falso.

Na aula 30 quando fizermos exercícios comentado, vamos aprender a trabalhar com IF alinhados que serão tomadas de decisão uma dentro da outra, falaremos disso no exercício em vídeo aula pois ficara mais fácil

Abaixo segue o link dessa vídeo aula em meu canal manual de Cad no youtube.

https://www.youtube.com/watch?v=hJigRvlObTs&feature=youtu.be

Espero que tenham gostado

Sergio Fernandes

Manual de Cad. 

Aula 27–Operadores Lógicos

Olá pessoal vamos dar continuidade nesse ciclo de aulas que nos levarão a entender e dominar o conceito de tomada de decisão em Autolisp. Hoje aprenderemos três operadores que são essenciais quando o assunto é tomada de decisão, estou falando dos operadores lógicos  AND, OR e NOT.

Operador AND

Esse operador retornara o resultado como T (verdadeiro), quando todas as condições ou comparações retornarem verdadeiro.

Exemplos:

(and (= “casa” “casa”) (> 10 5)) retorna T

Esse exemplo retornará verdadeiro (T) porque (= “casa” “casa”)  é verdadeiro e (> 10 5)) também é verdadeiro, como as duas condições são verdadeiras o operador and retornara o valor T (verdadeiro).

(setq idade30)

(setq peso 90)

(and (> peso 80) (< idade 25)) retorna nil

Esse exemplo retornara falso (nil) porque (> peso 90) é verdadeiro como a variável peso é 90 e 90 é maior que 80 isso torna a condição verdadeira, porem (< idade 25) é falso porque a variável idade é 30 que é maior que 25 e não menor como manda a condição, como uma das condições é falsa isso torna toda a condição falsa, porque todas as condições dentro do operador logico AND tem que ser verdadeiras.

Operador OR

Esse operador retornara o resultado como T (verdadeiro), quando qualquer uma das condições ou comparações retornarem verdadeiro.

Exemplo:

(or (= “casa” “Armario”) (= 10 20) (> 3 1)) Retorna T

Nesse exemplo apenas a condição (> 3 1) é verdadeira, pois 3 é maior do que 1, as outras são falsas, porem o operador logico OR retornará verdadeiro, pois basta que apenas uma das condições seja verdadeira para que a condição seja verdadeira.

Operador NOT

O operador NOT inverte a verdade quando uma condição é falsa ele retorna verdadeiro e quando é verdadeira ele retorna falso.

Exemplo:

(not (= 1 2)) retorna T

Essa linha retornou verdadeiro porque o operador logico NOT inverteu a verdade, (= 1 2) 1 não é igual a 2 que retorna nil, porem o operador NOT alterou isso para T verdadeiro.

Embora pareça sem utilidade (e na verdade é bem isso mesmo) o operador not pode ajudar em alguns casos.

Podemos também juntar vários operadores lógicos e formar condições de decisão mais elaboradas, vamos ver alguns exemplo abaixo:

(setq n1 10)
(setq n2 20)
(setq n3 30)
(setq ok 1)
(setq cancel 0)

(or (and (> n3 n2) (> n2 n1)) (= ok 0))
(and (or (= ok 1) (= cancel 1)) (or (> n1 n2)(> n2 n3)))

Vamos analisar cada uma dessas condições e verificar se o resultado será um valor falso ou verdadeiro.

(or (and (> n3 n2) (> n2 n1)) (= ok 0))

Acima temos um operador logico OR, ele retornará verdadeiro se qualquer uma das condições for verdadeira, acima temos duas condições uma pintada de amarelo e outra pintada de verde.

Primeiro analisaremos a condição amarela, dentro dela temos uma função AND, então sabemos que para ela retornar verdadeiro todas as condições dentro dela devem ser verdadeiras. A primeira é (> n3 n2) que é verdadeira, pois n3 vale 30 e n2 vale 20, a segunda é (> n2 n1) que também retornara verdadeira, pois n2 vale 20 e n1 vale 10, portanto como ambas as condições são verdadeiras o operador AND retornara o valor verdadeiro.

Agora vamos analisar a condição em verde, (= ok 0), essa condição retornara falso por OK na verdade vale 1.

Temos agora dois resultado dentro da função OR uma verdadeiro e outro falso, portanto o resultado final será verdadeiro. Lembre-se que o operador OR retorna verdadeiro se qualquer uma das condições apresentadas for verdadeira.

Agora vamos ver o segundo exemplo.

(and (or (= ok 1) (= cancel 1)) (or (> n1 n2) (> n2 n3)))

Acima temos o operador lógico AND, de antemão sabemos que todas as condições terão que ser verdadeiras para que o operador AND retorne verdadeiro (T), caso contrario ele retornará falso (nil). Da mesma forma temos duas condições uma amarela e outra verde.

A  condição amarela é composta por um operador OR, que verificara duas condições de igualdade, (= ok 1) será verdadeiro (T), pois o valor de OK é realmente 1, e (= cancel 1) será falso (nil), porem o resultado disso será (T) verdadeiro porque pelo menos uma das condições foi verdadeira.

A condição verde também é comporta pelo operador OR e verificara se dois elementos são realmente maiores que que o elemento comparado, o primeiro é (> n1 n2), falso, pois n1 vale 10 e n2 vale 20, depois (> n2 n3), também falso, pois n2 vale 20 e n3 vale 30, portanto o valor retornado será (nil) falso, pois nenhuma das condições foi verdadeira.

Temos dois resultados das condições um verdadeiro e outro falso, portanto como o operador final é o AND o resultado será falso, pois o operador AND precisa que todas as condições por ela avaliada sejam verdadeiras.

Abaixo segue o link da vídeo aula no meu canal Manual de Cad no youtube.

https://www.youtube.com/watch?v=XDBpUICQ_lc&feature=youtu.be

Espero que tenham gostado.

Sergio Fernandes

Manual de Cad

Aula 26–Operadores de Comparação

Olá pessoal, hoje começaremos a dar inicio a matéria de tomada de decisões, porem antes precisamos aprender os operadores de comparação e na proxima aula aprenderemos os operadores lógicos, eles são de fácil entendimento e a única coisa que precisamos sempre lembrar é que os operadores lógicos e os operadores de comparação só retomam dois tipos de valores para o programa:

Nil = false

T = verdadeiro

Toda vez que um operador retornar nil é que a comparação é falsa, se o retorno for T (true) o operador será verdadeiro.

Abaixo segue a lista dos operadores lógicos e alguns exemplos:

Operadores de Comparação:

= (Igual) ou eq (igual)

Verifica se um ou mais elementos são iguais

(= 100 100) retorna T      OU      (eq 100 100) retorna T

(= “a” “a”) retorna T      OU      (eq “a” “a”) retorna T

(= “A” “a”) retorna nil      OU      (eq “A” “a”) retorna nil

(= 10 30) retorna nil      OU      (eq 10 30) retorna nil

(= 100 (* 50 2)) retorna T      OU      (eq 100 (* 50 2)) retorna T

 

/= (Diferente)

Verifica se um ou mais elementos são diferentes.

(/= 100 100) retorna nil

(/= “a” “a”) retorna nil

(/= “A” “a”) retorna T

(/= 10 30) retorna T

(/= 100 (* 50 2)) retorna nil

 

> (Maior)

Verifica se um elemento é maior do que o outro.

(> 100 50) retorna T

(> 2 100) retorna nil

(> 30 (- 40 10)) retorna nil (o resultado é igual, portanto não é maior).

(> (+ 10 10) (+ 5 4)) retorna T

 

< (Menor)

Verifica se um elemento é menor do que o outro.

(< 100 50) retorna nil

(< 2 100) retorna T

(< 30 (- 40 10)) retorna nil (o resultado é igual, portanto não é menor).

(< (+ 10 10) (+ 5 4)) retorna nil

 

>= (Maior ou igual)

Verifica se um elemento é maior ou igual ao outro.

(>= 100 50) retorna T

(>= 2 2) retorna T

(> 30 (- 40 10)) retorna T

(>= (+ 10 10) (+ 5 4)) retorna T

 

<= (Menor ou igual)

Verifica se um elemento é menor ou igual ao outro.

(<= 100 50) retorna nil

(<= 2 2) retorna T

(<= 30 (- 40 10)) retorna T

(<= (+ 10 10) (+ 5 4)) retorna nil

 

Equal (Equivalente)

Essa função verifica se dois elementos são iguais, diferente dos demais operadores esse operador pode verificar a igualdade entre duas listas.

(equal 20 20 ) retorna T

(equal 20 10) retorna nil

(equal “a” “a”) retorna T

(equal (list 1 2 3) (list 1 2 3)) retorna T

(equal (list “a” “b”) (list “b” “a”)) retorna nil

Diferente das demais a função EQUAL aceita um tolerância para isso devemos informar o valor dessa tolerância.

(setq a 123.3456)

(setq b 123.3457)

(equal a b) retornara nil

(equal a b 0.0001) retornara T

O mesmo acontecera com listas mais complexas.

(setq lista1 (list 10.1 20.1 30.4 25.6))

(setq lista2 (list 10 20 30.3 25.7))

(equal lista1 lista2 0.1) retornara T

Na próxima aula falaremos sobre os operadores lógicos.

Abaixo segue o link dessa vídeo-aula no meu canal manual de Cad no youtube.

https://www.youtube.com/watch?v=rxDq_yJ8BLE&feature=youtu.be

Espero que tenham gostado.

Sérgio Fernandes

Manual de Cad 

Aula 25–Tratamento de Erros

 

Olá pessoal, algumas aulas atrás aprendemos como guardas as variáveis de sistemas e como restaura-las no final do nosso programa, isso se torna muito útil, pois não alteramos o ambiente de trabalho que estava ativo antes da execução do programa, porem isso apenas funciona se o programa tiver um começo um meio e um fim, caso o programa for cancelado durante sua execução ou algum erro de programação aconteça o programa não vai restaurar as variáveis de sistema, para contornar esse problema aprenderemos hoje como alterar a função de erro do AutoCAD, dessa forma quando um erro acontecer podemos informar quais ações devem ser executas e assim garantir que as variáveis de sistemas sejam novamente restauradas.

Variável *error*

Existe no AutoCAD uma variável padrão que contem todas as mensagens de erros, sejam esses error causados por mau uso do programa, cancelado por parte do usuário ou um erro de programação, o que precisamos fazer é armazenar o valor dessa variável *erro* (sim essa variável se escreve com asteriscos), para fazer isso basta criar uma nova variável com o conteúdo da variável *error*.

(setq erro_antigo *error*)

Agora temos uma variável chamada erro_antigo que contem todos os dados da função de erro do AutoCAD, agora como já criamos de certa forma um backup desse *error* podemos altera-lo da maneira que quisermos, pois poderemos restaura-lo.

Função *error*

Agora precisamos criar uma nova função *error* (sim todo o conteúdo da variável *error* é uma função) e nela podemos fazer o que quisermos ate mesmo mudar as mensagens de erro.

Primeiro vamos criar um função que armazene todas as variáveis de sistema que vamos modificar e logico a própria função *error*.

(defun guarda_variaveis ()
  (setq cmdecho (getvar "cmdecho"))
  (setq orthomode (getvar "Orthomode"))
  (setq osmode (getvar "osmode"))
  (setq clayer (getvar "clayer"))
  (setq cecolor (getvar "cecolor"))
  (setq filedia (getvar "filedia"))
  (setq attreq (getvar "attreq"))
  (setq attdia (getvar "attdia"))
  (setq erro_antigo *error*)
  )

Note que armazenamos na variável erro_antigo a função *error*

Agora uma função que restaure as variáveis.

(defun restaura_variaveis()
  (setvar "cmdecho" cmdecho)
  (setvar "Orthomode" Orthomode)
  (setvar "osmode" osmode)
  (setvar "clayer" clayer)
  (setvar "cecolor" cecolor)
  (setvar "filedia" filedia)
  (setvar "attreq" attreq)
  (setvar "attdia" attdia)
  )

Agora criamos a nossa função de erro, vamos chama-la de meu_erro.

(defun meu_erro (MSG)
(setq *error* erro_antigo)
(restaura_variaveis)
(prompt "\nComando cancelado!")
)

Note que restauramos a função  *error* que estava armazenada na variável erro_antigo.

Para finalizar precisamos dizer ao Autolisp que essa agora é a nova função  *error*.

(setq *error* Meu_erro)

Vamos ver como ficaria um programa com a chamada para esse novo erro.

(defun c:tt()
  (guarda_variaveis)
  (setq *error* meu_erro)
  (setq nome (getstring "\nDigite o seu primeiro nome: "))
  (setq pt1 (getpoint "\nClique sobre o local desejad: "))
  (command "text" pt1 "2" "0" nome)
  (restaura_variaveis)
  )

Pronto, agora toda vez que um erro acontecer à função meu_erro será chamada, quando isso acontecer ele vai restaurar as variáveis de sistema e alterar a função *error* para a sua função original.

É importantíssimo voltar a função *erro* para o original caso contrario todas as mensagens de erro do AutoCAD serão igual à função meu_erro, caso você esqueça esse procedimento, fique tranquilo pois quando o desenho for fechado e aberto a função *error* padrão será carregada automaticamente pelo AutoCAD.

Assistam a vídeo aula pois nela será explicado passo a passo como isso se comporta dentro de um programa.

Abaixo segue o link do meu canal Manual de Cad no youtube.

https://www.youtube.com/watch?v=WLJZN_k6wag&feature=youtu.be

Espero que tenham gostado

Sérgio Fernandes.

Manual de Cad.

 

 

Aula 24–Exercícios Funções

 

Olá pessoal, nessa aula teremos apenas a veio aula no nosso canal Manual de Cad no youtube. Abaixo segue o link.

https://www.youtube.com/watch?v=ePSQkPkrI18&feature=youtu.be

Espero que tenham gostado

Sérgio Fernandes

Manual de Cad.